Working With Named Ranges In Excel 

What Are Named Ranges?

Named Ranges are a powerful tool in Excel that allows you to assign a meaningful name to a single cell or a range of cells. For example, you can assign the name "TaxRate" to cell C1 and then use the name "TaxRate" anytime you would normally use the cell C1, such as =A5*TaxRate. 

There are 3 advantages to using Named Ranges: 

· Formulas are more readable and meaningful. A formula like =A5*TaxRate is more meaningful to you when you are working with a complex worksheet. 

· Named Ranges, by default, always use absolute cell references. Therefore, you don't have to worry about address translation, which occurs with relative cell references, when you Copy/Paste or Fill Down/Right cell ranges.

·  Named Ranges make it easier to create well organized and attractive workbooks. You can use a named reference, rather than a cell address, in formulas, and then define that name to a specific cell after you've designed the workbook. With Named Ranges, you won't have to edit and change the dependent formulas. Just change the reference of the name. 

Valid Range Names

A range name can contain letters, numbers, and underscores, but not spaces or special punctuation characters. Moreover, it cannot be the same as a normal cell reference. For example, "AA10" is not a valid range name because "AA10" is the name of a normal cell reference (row 10, column "AA"). 

While it is perfectly legal as far as Excel is concerned to use a Name with the same name as worksheet (e.g., you can have the odd situation of having the name 'Sheet1' refer to a cell on the worksheet 'Sheet2'), I would strong recommend against this. It will lead only to confusion. 

Adding And Deleting Named Ranges

To create a new Named Range from Excel, use the following procedure: 
Select the cell or range of cell that you want to assign a name to. Go to the Insert menu, select the Name menu item, and type your name in the text box.
To delete a named range, go to the insert menu, select the Name menu item, then select the name from this list, and click the Delete button.

Naming Formulas

A Named Range does not have to refer to a cell or a range of cells. It can refer to a formula. However, all of the arguments to the formula are "static". They do not depend on the cell from which the name is invoked. You should always use absolute cell references in a named formula; otherwise the result can be very confusing.

For example, if you frequently use the formula =SUM($A$1:$A$10), you can create a named formula called MySum, referring to the formula =SUM($A$1:$A$10). Then, you can use the name anywhere you'd normally use the formula: =MySum/2
Another advantage is that you can overcome Excel's limitation on eight nested functions

Dynamic Ranges

It is often useful to create a name that refers to a range of cells, where the range depends on the content of the cells. For example, you may want a name that refers to the first N non-blank entries in column A. Excel's Name tool allows you to do this. For example, creating a name called DynaRange, referring to

=OFFSET(Sheet1!$A$1,0,0,COUNTA(Sheet1!$A:$A),1)
If the first 20 rows of column A contain data (and the rest are blank), DynaRange will refer to the range A1:A20
See the on-line help for the =OFFSET function for a description of the arguments. Setting the Width argument to 2 will allow us to use this name in a =VLOOKUP function

=OFFSET(Sheet1!$A$1,0,0,COUNTA(Sheet1!$A:$A),2)

Then, call VLOOKUP with the DynaRange argument for the lookup range:

=VLOOKUP(C1, DynaRange, 2)

As data is added to columns A and B, the range search by VLOOKUP will extend to include the new data.


Defined Names In Data Validation And Conditional Formatting

When you use the Data Validation tool, you can restrict valid inputs to the values in another range. However, the Data Validation dialog won't allow you to specify cells on another worksheet. But using a defined name, you can get around this limitation. Simply give the range containing the valid values a name, such as ValidRange, and then in the Data Validation dialog, enter =ValidRange as the Source for the validation list. Data Validation won't object, and everything will work as you expect. 

You can use the same technique with Conditional Formatting. The Conditional Formatting objects when you try to use a reference to a cell or range on another worksheet. Just name the source cell or range, and use the defined name in the Conditional Formatting formulas. CF won't object, and everything will work as you expect.
VBA Procedure For Working With Names

Adding A Range Name 

You can use the Add method of the Names collection object to add a new defined name. 

ThisWorkbook.Names.Add Name:="NewName", _

                  RefersTo:="=$A$1:$C$10", Visible:=True
If you set the Visible property of the name to False, the name will not be displayed in the Names dialog box, although the name can still be used normally in VBA procedures and worksheet formulas. 
If you add a name that already exists, Excel will replace the old name with the new name. An error will not be generated. 
Determining Whether A Name Exists 

The following VBA procedure will return TRUE if the name specified in TheName exists, or will return FALSE otherwise. 

Function NameExists(TheName As String) As Boolean
     On Error Resume Next
     NameExists = Len(ThisWorkbook.Names(TheName).Name) <> 0
End Function

Deleting A Name 
The Delete method of the Names collection can be used to delete a name. 
     ThisWorkbook.Names("NewName").Delete
If the name does not exist, a run time error will occur. 
Determining The Name Of A Cell Or Range 

You can use VBA procedures to determine the define named that contains a given cell or range. You must first decide whether you want to return a name that refers to some range that intersects with your range, or whether you want to return the name of the range that refers to exactly the same range or cell as your range. Below are two VBA procedures to do this. 
Function NameOfParentRange(Rng As Range) As String
     Dim Nm As Name
     For Each Nm In ThisWorkbook.Names
         If Rng.Parent.Name = Nm.RefersToRange.Parent.Name Then
            If Not Application.Intersect(Rng, Nm.RefersToRange) _ 
               Is Nothing Then
               NameOfParentRange = Nm.Name
               Exit Function
           End If
         End If
     Next Nm
     NameOfParentRange = ""
End Function

This procedure will return the name of the range that intersects with the range specified by the Rng argument. For example, if the name Range1 refers to A1:A10, and Rng is A5:D5, the function will return "Range1" because the range A5:D5 intersects with A1:A10. With this function, Rng does not have be exactly match a defined range -- there simply must be a non-empty intersection between the two. 
If you need an exact match, use the function below. 
Function ExactRangeName(Rng As Range) As String
     On Error Resume Next
     ExactRangeName = Rng.Name.Name
End Function
With this function, if the name Range1 refers to A1:A10, the function will return an empty string unless Rng refers to exactly A1:A10. 
There is another class of Name in Excel, whose values are available to all open workbooks, and whose values are retained even after the workbook which created the name has been closed.

Finding the Used Part of a Range

Suppose we've got a range of data called DataRange2, defined as H7:I25, and that cells H7:I17 actually contain values.  The rest are blank. We can find various properties of the range, as follows :

· To find the range that contains data, use the following Array Formula :

          {=ADDRESS(ROW(DataRange2),COLUMN(DataRange2),4)&":"&

           ADDRESS(MAX((DataRange2)<>"")*ROW(DataRange2)),COLUMN(DataRange2)+

           COLUMNS(DataRange2)-1,4)}

    … This will return the Range H7:I17

· If you need the worksheet name in the returned range, use the following array formula :

        {=ADDRESS(ROW(DataRange2), COLUMN(DataRange2),4,,"My Sheet"))&":"&

          ADDRESS(MAX((DataRange2)<>"")*ROW(DataRange2)),COLUMN(DataRange2)+

          COLUMNS(DataRange2)-1,4)}

… This will return MySheet!H7:I17

· To find the number of rows that contain data, use the following Array Formula :

{=(MAX((DataRange2<>"")*ROW(DataRange2)))-ROW(DataRange2)+1}

… This will return the number 11, indicating that the first 11 rows of DataRange2 contain data

· To find the last entry in the first column of DataRange2, use the following array formula :

{=INDIRECT(ADDRESS(MAX((DataRange2<>"")*ROW(DataRange2)),

 COLUMN(DataRange2),4))}

· To find the last entry in the second column of DataRange2, use the following array formula :

{=INDIRECT(ADDRESS(MAX((DataRange2<>"")*ROW(DataRange2)),

 COLUMN(DataRange2)+1,4))}

About Excel's Hidden Name Space

The hidden name space is a memory area belonging to the current Excel instance, where add-in DLLs ("XLLs") can store temporary names. With this area, XLLs can define names even though there is no macro sheet available.

The manipulation of hidden names are based on the XLM functions SET.NAME, GET.NAME and EVALUATE. Whereas SET.NAME defines a normal sheet-level name when used in an XLM macro sheet, it creates an application-level name and stores it in the hidden area when it is called in an XLL.

The names defined in this hidden area have some special features, which make them very different from the standard workbook names. These features will be described later.

The available C API commands related to hidden names are :

Excel4(xlfSetName,&xResult,2,&xName,&xValue);
... defines the name xName containing xValue

Excel4(xlfGetName,&xResult,1,&xName);
... retrieves the definition (for instance, "=1") of xName and stores it in xResult

Excel4(xlfEvaluate,&xResult,1,&xName);
... retrieves the contents of xName (for instance : 1) and stores it in xResult

Excel4(xlfSetName,&xResult,1,&xName);
... deletes xName (second argument missing)


Accessing the hidden name space in VBA

Although it should not be possible (following the SDK), the hidden name space is accessible not only to DLLs, but also to VBA modules (and even worksheets). The undocumented trick consists simply in calling the XLM function SET.NAME in the VBA module with the ExecuteExcel4Macro method :

Creating A Hidden Name

To create a hidden name named Test, containing the string "OK", use

Application.ExecuteExcel4Macro "SET.NAME(""Test"",""OK"")"

Retrieving The Contents Of A Hidden Name

To retrieve the contents of the name Test, use

TestVal = Application.ExecuteExcel4Macro("Test")

(just use the name itself as the argument of ExecuteExcel4Macro)

Deleting A Hidden Name

To delete the name Test, use

Application.ExecuteExcel4Macro "SET.NAME(""Test"")"

(second argument of SET.NAME missing)

Accessing The Hidden Name Space In Worksheets

The hidden names can be also accessed directly in worksheet formulae. You must use SET.NAME and EVALUATE in combination with CALL() and the API function. The numbers of the functions SET.NAME and EVALUATE are 88 and 257, respectively .

Creating A Hidden Name
To create a hidden name named Test, containing the string "OK", use

=CALL("Xlcall32","Excel4","2JRJRR#",88,,2,"Test","OK")

Retrieving The Contents Of A Hidden Name

To retrieve the contents of the name Test, use

=CALL("Xlcall32","Excel4","2JRJR#",257,,1,"Test")

Deleting A Hidden Name

To delete the name Test, use

=CALL("Xlcall32","Excel4","2JRJRR#",88,,1,"Test")

Defining and deleting hidden names directly in worksheet formulas is possible, because SET.NAME is not a command (like DEFINE.NAME), but a macro control function.

The hidden names can be used in macro sheets in the same way, except that you don't need to append the number sign to the type string.


Features Of The Hidden Name Space

The main feature of names defined in the hidden name space is that they don't belong to any workbook, but to the application itself.

This feature means in particular that :

These name can be accessed directly anywhere in Excel

Any VBA module, worksheet or macro sheet located in any workbook (and of course any DLL add-in) can read and modify them directly, no matter which workbook created the name.

Their "life time" corresponds to the current Excel session.

If you create such a name in a VBA module of the workbook Wbk1.xls, and then close this workbook, the name is still stored in the hidden name space. If you then open another workbook, Wbk2.xls, its VBA procedures can still retrieve and modify this hidden name, even though it was created by Wbk1.xls. Names defined in the hidden name space can be used as permanent "public variables" accessible without limitation from any VBA add-in.

As these hidden names belong to the application, closing all workbooks and add-ins won't destroy them. They can only be destroyed either by an explicit call to SET.NAME (without the second argument), or by quitting and restarting Excel. In this matter, these names can be used as a sort of Excel environmental variables.

They are "very hidden"

When a protected add-in uses the hidden name space, the new names can't be read by any other VBA module, nor by the user, unless they know their identification. There is no way to "list" the names that are defined in the hidden name space.

These names must not be confused with standard hidden names (workbook or sheet names whose .Visible property has been set to False). Standard workbook-level names are never really hidden, because they can be read and modified by any VBA procedure through the Application.Names collection, as shown below :

Dim CName As Name
For Each CName In Workbooks("Wbks1.xls").Names
If CName.Hidden Then
MsgBox CName.Name & " deleted"
CName.Delete
End If
Next CName

This code, which loops through all hidden names in Wbks1.xls and delete them, will fail to detect the existence of the names stored in the hidden name space, because they simply don't belong to the Application.Names collection. Consequently, they are protected against any undesirable access or modification.


Examples 

The following code illustrates a possible use of the hidden name space in a VBA protected add-in demo.

It prevents the user from executing the main Sub of the add-in more than three times in the same Excel session. The counter of the allowed remaining executions is not stored in a module-level variable nor in a name attached to the add-in, but in the hidden name space.

Using the name space prevents the user from breaking the protection by eliminating the following weakness of more conventional methods: 

· Like all variables, a counter stored in a VBA variable can be cleared manually in the VB Editor (Execution -> Initialize).

· In the same way, all workbook names of the add-in (hidden or not) can be read, modified and possibly deleted by any external Sub which would loop through the Names collection of the add-in. 

The hidden name space avoids both risks; it is also simpler than other methods based for instance on environment strings, temporary files or registry entries. As the hidden name space is permanent, the user can close and re-open the workbook, without resetting the counter.

In this code, the functions SetHName, GetHName and DelHName allow you to create, read, and delete hidden names without having to use directly the verbose Application.ExecuteExcel4Macro method.

Sub Main()
     Application.EnableCancelKey = xlDisabled
     Dim Count
     Count = GetHName("TswbkCount")
     If IsError(Count) Then
        SetHName "TswbkCount", 3
     ElseIf Count = 1 Then
        MsgBox "Macro disabled. You must restart Excel.", vbInformation
     Else
        SetHName "TswbkCount", Count - 1
     End If
End Sub

Sub SetHName(Name As String, Value)
     Application.ExecuteExcel4Macro _
        "SET.NAME(""" & Name & """," & Value & ")"
End Sub


Function GetHName(Name As String)
     GetHName = Application.ExecuteExcel4Macro(Name)
End Function


Sub DelHName(Name As String)
     Application.ExecuteExcel4Macro "SET.NAME(""" & Name & """)"
End Sub

I have expanded upon the information presented above to create a .bas file named EX00A.bas that contains the following functions.

IsValidName

Public Function IsValidName(HiddenName As String) As Boolean
This function returns True or False indicating whether HiddenName is a valid name. The following characters, and the space characters, are invalid in names: / - : ; ! @ # $ % ^ & *( ) + = , < > 


HiddenNameExists

Public Function HiddenNameExists(HiddenName As String) As Boolean
This function returns True or False indicating whether the hidden name exists.

AddHiddenName 

Public Function AddHiddenName(HiddenName As String, NameValue As Variant, _

    

Optional OverWriteExisting As Boolean = False) As Boolean
This function adds a new name to the hidden name space. If the name does not exist, it is added and function returns True. If the name exists, and OverWriteExisting is omitted or False, the function returns False. If OverWriteExisting is True, the original name is deleted and recreated with the new value.

DeleteHiddenName

Public Sub DeleteHiddenName(HiddenName As String)
This procedure deletes HiddenName. If the name does not exist, no action is taken. This procedure does not return a value.

GetHiddenNameValue

Public Function GetHiddenNameValue(HiddenName As String) As Variant
This function returns the value of HiddenName if it exists and is a valid name. It returns NULL if an error occcurred. Note that the return value is always a String type variable. 

The entire contents of the EX00A.bas is shown below:

Option Explicit

Option Compare Text

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

' modHiddenNames

' By Chip Pearson, www.cpearson.com , chip@cpearson.com

'

' This module expands on "HiddenNameSpace" as documented by Laurent Longre at

' "www.cpearson.com/excel/hidden.htm". This code is my own, but concept comes from

' Laurent Longre.

' Note that these names persist as long as the application is running, even if the

' workbook that create then names (or any other workbook) is closed.

'

' This module contains the following procedures for working with names in the hidden name

' space in Excel.

'           HiddenNameExists

'               Returns True or False indicating whether then specified name exists.

'           IsValidName

'               Returns True or False indicating whether the specified name is valid.

'           AddHiddenName

'               Adds a hidden name and value. Optionally overwrites the name if it

'               already exists.

'           DeleteHiddenName

'               Deletes a name in the hidden name space. Ignores the condition if the

'               name does not exist. This function does not return a value.

'           GetHiddenNameValue

'               Returns the value of a hidden if that name exists. Returns the value of the

'               name if it exists, or NULL if it does not exist.

'

' To change the value of an existing name, first call DeleteHiddenName to remove the name,

' then call AddHiddenName to add the name with the next value.

'

' There is no way to enumerate the existing names. You must know the name in order to

' access or delete it.

'

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

Private Const C_ILLEGAL_CHARS = " /-:;!@#$%^&*()+=,<>"

Public Function IsValidName(HiddenName As String) As Boolean

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

' IsValidName

' This function returns True if HiddenName is a valid name, i.e., it

' is not an empty string and does not contain any character in the

' C_ILLEGAL_CHARS constant.

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

Dim C As String

Dim NameNdx As Long

Dim CharNdx As Long

If Trim(HiddenName) = vbNullString Then

    IsValidName = False

    Exit Function

End If

''''''''''''''''''''''''''''''''''''

' Test each character in HiddenName

' against each character in

' C_ILLEGALCHARS. If a match is

' found, get out and return False.

'''''''''''''''''''''''''''''''''''

For NameNdx = 1 To Len(HiddenName)

    For CharNdx = 1 To Len(C_ILLEGAL_CHARS)

        If StrComp(Mid(HiddenName, NameNdx, 1), Mid(C_ILLEGAL_CHARS, CharNdx, 1), vbBinaryCompare) = 0 Then

            ''''''''''''''''''''''''''''' 

            ' Once one invalid character 

            ' is found, there is no

            ' need to continue. Get out

            ' with a result of False.

            '''''''''''''''''''''''''''''

            IsValidName = False

            Exit Function

        End If

    Next CharNdx

Next NameNdx

''''''''''''''''''''''''''''''

' If we made out of the loop,

' the name is valid.

''''''''''''''''''''''''''''''

IsValidName = True

End Function

Public Function HiddenNameExists(HiddenName As String) As Boolean

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

' HiddenNameExists

' This function returns True if the hidden name HiddenName

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

Dim V As Variant

On Error Resume Next

''''''''''''''''''''''''''''''''''''''''

' Ensure the name is valid

''''''''''''''''''''''''''''''''''''''''

If IsValidName(HiddenName) = False Then

    HiddenNameExists = False

    Exit Function

End If

V = Application.ExecuteExcel4Macro(HiddenName)

On Error GoTo 0

If IsError(V) = False Then

    ''''''''''''''''''''''''''''''

    ' No error. Name exists.

    ''''''''''''''''''''''''''''''

    HiddenNameExists = True

Else

    ''''''''''''''''''''''''''''''

    ' Error. Name does not exists.

    ''''''''''''''''''''''''''''''

    HiddenNameExists = False

End If

End Function

Public Function AddHiddenName(HiddenName As String, NameValue As Variant, _

    Optional OverWriteExisting As Boolean = False) As Boolean

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

' AddHiddenName

' This adds the hidden name HiddenName with a value NameValue to Excel's

' hidden name space. If OverWriteExisting is omitted or False, the function

' will not overwrite the existing name and will return False if the name

' already exists. If OverWriteExisting is True, the original name is

' deleted and replace with the values passed to this function, and the

' function will return True.

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

Dim V As Variant

Dim Res As Variant

''''''''''''''''''''''''''''''''''''''''

' Ensure the name is valid

''''''''''''''''''''''''''''''''''''''''

If IsValidName(HiddenName) = False Then

    AddHiddenName = False

    Exit Function

End If

'''''''''''''''''''''''''''''''''

' If V is an object, an array,

' or a user-defined type, then

' return False.

''''''''''''''''''''''''''''''''

If VarType(V) >= vbArray Then

    AddHiddenName = False

    Exit Function

End If

If (VarType(V) = vbUserDefinedType) Or (VarType(V) = vbObject) Then

    AddHiddenName = False

    Exit Function

End If

'''''''''''''''''''''''''''''''''

' Test to see if the name exists.

'''''''''''''''''''''''''''''''''

On Error Resume Next

V = Application.ExecuteExcel4Macro(HiddenName)

On Error GoTo 0

If IsError(V) = False Then

    '''''''''''''''''''''''''''''

    ' Error. Name Exists. If

    ' OverWriteExisting is False,

    ' exit with False. Otherwise

    ' delete the name.

    '''''''''''''''''''''''''''''

    If OverWriteExisting = False Then

        AddHiddenName = False

        Exit Function

    Else

        DeleteHiddenName HiddenName:=HiddenName

    End If

End If

V = Application.ExecuteExcel4Macro("SET.NAME(" & Chr(34) & HiddenName & Chr(34) & "," & Chr(34) & NameValue & Chr(34) & ")")

If IsError(V) = True Then

    AddHiddenName = False

Else

    AddHiddenName = True

End If

End Function

Public Sub DeleteHiddenName(HiddenName As String)

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

' DeleteHiddenName

' This deletes an name from Excel's hidden name space. It ignores the

' condition that the name does not exist. The procedure does not return

' an result.

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

On Error Resume Next

Application.ExecuteExcel4Macro ("SET.NAME(" & Chr(34) & HiddenName & Chr(34) & ")")

End Sub

Public Function GetHiddenNameValue(HiddenName As String) As Variant

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

' GetHiddenNameValue

' This function returns the value of HiddenName. If the name does

' not exist, the function returns NULL. Otherwise, it returns the

' value of HiddenName. Note that the value returned by this function

' is always a string value. You'll have to convert it to another

' data type is desired.

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

Dim V As Variant

''''''''''''''''''''''''''''''''''''''''

' Ensure the name is valid

''''''''''''''''''''''''''''''''''''''''

If IsValidName(HiddenName) = False Then

    GetHiddenNameValue = Null

    Exit Function

End If

If HiddenNameExists(HiddenName:=HiddenName) = False Then

    GetHiddenNameValue = Null

    Exit Function

End If

On Error Resume Next

V = Application.ExecuteExcel4Macro(HiddenName)

On Error GoTo 0

If IsError(V) = True Then

    GetHiddenNameValue = Null

    Exit Function

End If

GetHiddenNameValue = V

End Function
Dynamic Ranges
You can define a name to refer to a range whose size varies depending on its contents. For example, you may want a range name that refers only to the portion of a list of numbers that are not blank. such as only the first N non-blank cells in A2:A20. Define a name called MyRange, and set the Refers To property to:

     =OFFSET(Sheet1!$A$2,0,0,COUNTA($A$2:$A$20),1)

Be sure to use absolute cell references in the formula.

Finding The Used Part Of A Range

Suppose we've got a range of data called DataRange2, defined as H7:I25, and that 
cells H7:I17 actually contain values. The rest are blank. We can find various properties 
of the range, as follows: 

To find the range that contains data, use the following ARRAY FORMULA :

=ADDRESS(ROW(DataRange2),COLUMN(DataRange2),4)&":"&
ADDRESS(MAX((DataRange2<>"")*ROW(DataRange2)),COLUMN(DataRange2)+
COLUMNS(DataRange2)-1,4)
… This will return the range H7:I17. 

If you need the worksheet name in the returned range, 
use the following ARRAY FORMULA :

=ADDRESS(ROW(DataRange2),COLUMN(DataRange2),4,,"MySheet")&":"&
ADDRESS(MAX((DataRange2<>"")*ROW(DataRange2)),COLUMN(DataRange2)+
COLUMNS(DataRange2)-1,4)

… This will return MySheet!H7:I17.

To find the number of rows that contain data, use the following ARRAY FORMULA :

=(MAX((DataRange2<>"")*ROW(DataRange2)))-ROW(DataRange2)+1

… This will return the number 11, indicating that the first 11 rows of DataRange2 contain data.

To find the last entry in the first column of DataRange2, use the following ARRAY FORMULA :

=INDIRECT(ADDRESS(MAX((DataRange2<>"")*ROW(DataRange2)),
COLUMN(DataRange2),4))

To find the last entry in the second column of DataRange2, use the following ARRAY FORMULA :

=INDIRECT(ADDRESS(MAX((DataRange2<>"")*ROW(DataRange2)),

COLUMN(DataRange2)+1,4))

First And Last Names
Suppose you've got a range of data consisting of people's first and last names.
There are several formulas that will break the names apart into first and last names
separately. 

Suppose cell A2 contains the name "John A Smith".

To return the last name, use

     =RIGHT(A2,LEN(A2)-FIND("*",SUBSTITUTE(A2," ","*",LEN(A2)-
     LEN(SUBSTITUTE(A2," ","")))))

To return the first name, including the middle name (if present), use

     =LEFT(A2,FIND("*",SUBSTITUTE(A2," ","*",LEN(A2)-
     LEN(SUBSTITUTE(A2," ",""))))-1)

To return the first name, without the middle name (if present), use

     =LEFT(B2,FIND(" ",B2,1))

We can extend these ideas to the following. Suppose A1 contains the string "First Second Third Last".

Returning First Word In A String

=LEFT(A1,FIND(" ",A1,1))

This will return the word "First".

Returning Last Word In A String

=RIGHT(A1,LEN(A1)-MAX(ROW(INDIRECT("1:"&LEN(A1))) 

*(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1)=" ")))

This formula in an array formula.

This will return the word "Last"

Returning All But First Word In A String

=RIGHT(A1,LEN(A1)-FIND(" ",A1,1))

This will return the words "Second Third Last"

Returning Any Word Or Words In A String

To return any single word from a single-spaced string of words, use the following array formula : 

=MID(A10,SMALL(IF(MID(" "&A10,ROW(INDIRECT
("1:"&LEN(A10)+1)),1)=" ",ROW(INDIRECT("1:"&LEN(A10)+1))),
B10),SUM(SMALL(IF(MID(" "&A10&" ",ROW(INDIRECT
("1:"&LEN(A10)+2)),1)=" ",ROW(INDIRECT("1:"&LEN(A10)+2))),
B10+{0,1})*{-1,1})-1)
Where A10 is the cell containing the text, and B10 is the number of the word you want to get. 

This formula can be extended to get any set of words in the string. 

To get the words from M for N words (e.g., the 5th word for 3, or the 5th, 6th, and 7th words), use the following array formula :
=MID(A10,SMALL(IF(MID(" "&A10,ROW(INDIRECT
("1:"&LEN(A10)+1)),1)=" ",ROW(INDIRECT("1:"&LEN(A10)+1))),
B10),SUM(SMALL(IF(MID(" "&A10&" ",ROW(INDIRECT
("1:"&LEN(A10)+2)),1)=" ",ROW(INDIRECT("1:"&LEN(A10)+2))),
B10+C10*{0,1})*{-1,1})-1)

Where A10 is the cell containg the text, B10 is the number of the word to get, and C10 is the number of words, starting at B10, to get. 

Note that in the above array formulas, the {0,1} and {-1,1} are enclosed in array braces (curly brackets {} ) not parentheses.



Grades

A frequent question is how to assign a letter grade to a numeric value. This is simple. First create a define name called "Grades" which refers to the array:

={0,"F";60,"D";70,"C";80,"B";90,"A"}

Then, use VLOOKUP to convert the number to the grade:

=VLOOKUP(A1,Grades,2)

where A1 is the cell contains the numeric value. You can add entries to the Grades array for other grades like C- and C+. Just make sure the numeric values in the array are in increasing order.

High And Low Values

You can use Excel's Circular Reference tool to have a cell that contains the highest ever reached value. For example, suppose you have a worksheet used to track team scores. You can set up a cell that will contain the highest score ever reached, even if that score is deleted from the list. Suppose the score are in A1:A10. First, go to the Tools->Options dialog, click on the Calculation tab, and check the Interations check box. Then, enter the following formula in cell B1:

=MAX(A1:A10,B1)

Cell B1 will contian the highest value that has ever been present in A1:A10, even if that value is deleted from the range. Use the =MIN function to get the lowest ever value.

Another method to do this, without using circular references, is provided by Laurent Longre, and uses the CALL function to access the Excel4 macro function library.

Left Lookups

The easiest way do table lookups is with the =VLOOKUP function. However, =VLOOKUP requires
that the value returned be to the right of the value you're looking up. For example, if you're
looking up a value in column B, you cannot retrieve values in column A. If you need to
retrieve a value in a column to the left of the column containing the lookup value, use
either of the following formulas:

=INDIRECT(ADDRESS(ROW(Rng)+MATCH(C1,Rng,0)-1,COLUMN(Rng)-ColsToLeft)) Or 
=INDIRECT(ADDRESS(ROW(Rng)+MATCH(C1,Rng,0)-1,COLUMN(A:A) ))

Where Rng is the range containing the lookup values, and ColsToLeft is the number of columns
to the left of Rng that the retrieval values are. In the second syntax, replace "A:A" with the
column containing the retrieval data. In both examples, C1 is the value you want to look up.

Minimum And Maximum Values In A Range

Of course you can use the =MIN and =MAX functions to return the minimum and maximum 
values of a range. Suppose we've got a range of numeric values called NumRange. 
NumRange may contain duplicate values. The formulas below use the following example:



Address Of First Minimum In A Range
To return the address of the cell containing the first (or only) instance of the minimum of a list, 
use the following Array Formula :

=ADDRESS(MIN(IF(NumRange=MIN(NumRange),ROW(NumRange))),COLUMN(NumRange),4)

This function returns B2, the address of the first '1' in the range.

Address Of The Last Minimum In A Range
To return the address of the cell containing the last (or only) instance of the minimum of a list, 
use the following Array Formula :

=ADDRESS(MAX(IF(NumRange=MIN(NumRange),ROW(NumRange)*(NumRange<>""))),
COLUMN(NumRange),4)

This function returns B4, the address of the last '1' in the range.

Address Of First Maximum In A Range
To return the address of the cell containing the first instance of the maximum of a list, 
use the following Array Formula :

=ADDRESS(MIN(IF(NumRange=MAX(NumRange),ROW(NumRange))),COLUMN(NumRange),4)

This function returns B1, the address of the first '5' in the range.

Address Of The Last Maximum In A Range
To return the address of the cell containing the last instance of the maximum of a list, 
use the following Array Formula :

=ADDRESS(MAX(IF(NumRange=MAX(NumRange),ROW(NumRange)*(NumRange<>""))),
COLUMN(NumRange),4)

This function returns B5, the address of the last '5' in the range.

Most Common String In A Range

The following Array Formula will return the most frequently used entry in a range:

=INDEX(Rng,MATCH(MAX(COUNTIF(Rng,Rng)),COUNTIF(Rng,Rng),0)) 

Where Rng is the range containing the data.

Ranking Numbers

Often, it is useful to be able to return the N highest or lowest values from a range of data. 
Suppose we have a range of numeric data called RankRng. Create a range next to 
RankRng (starting in the same row, with the same number of rows) called TopRng. 
Also, create a named cell called TopN, and enter into it the number of values you want to 
return (e.g., 5 for the top 5 values in RankRng). Enter the following formula in the first cell in 
TopRng, and use Fill Down to fill out the range: 

=IF(ROW()-ROW(TopRng)+1>TopN,"",LARGE(RankRng,ROW()-ROW(TopRng)+1))

To return the TopN smallest values of RankRng, use

=IF(ROW()-ROW(TopRng)+1>TopN,"",SMALL(RankRng,ROW()-ROW(TopRng)+1))

The list of numbers returned by these functions will automatically change as you change the 
contents of RankRng or TopN.

Removing Blank Cells In A Range


You can use a formula to return only the non-blank cells from a range. The following function will return all the cell values in a range named BlanksRange that are not empty. 

Create a range name, with the same number of rows as BlanksRange called NoBlanksRange. The range NoBlanksRange must have the same number of rows as BlanksRange but it need not be in the same row numbers. Enter the following Array Formula in the first cell of NoBlanksRange, and then use Fill Down to fill out the range: 

=IF(ROW()-ROW(NoBlanksRange)+1>ROWS(BlanksRange)- 
COUNTBLANK(BlanksRange),"",INDIRECT(ADDRESS(SMALL(
(IF(BlanksRange<>"",ROW(BlanksRange),ROW()+ROWS(BlanksRange))),
ROW()-ROW(NoBlanksRange)+1),COLUMN(BlanksRange),4)))
The first N rows of NoBlanksRange will contain the N non-blank cells of BlanksRange. Note that this is an array formula, so you must press Ctrl+Shift+Enter rather than just Enter when you first enter the formula and whenever you edit it later. If you do this properly, Excel will display the formula enclosed in curly braces { }.

Note that if you do not use named ranges and enter the actual cell references, you must use absolute cell references (e.g., $B$1) rather than relative cell references (e.g., B1).

Example

As you can see here, the values in BlanksRange 
are shifted up, as the blank entries are removed. 

You can also use VBA to create a NoBlanks Function. The code is shown below:

Function NoBlanks(DataRange As Range) As Variant()

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

' NoBlanks

' This function returns an array that consists of the non-blank values

' in DataRange. The function must be array-entered into the complete range

' of worksheet cells that are to receive the result. For example, if

' you want the results in B1:B10, select that range, type

'       =NOBLANKS(A1:A10)

' in B1 and press CTRL+SHIFT+ENTER rather than just enter.

' This will cause the function to fill B1:B10 with the N non-blank

' entries in A1:A10, and place vbNullStrings in N+1 to 10.

' The input DataRange must have exactly 1 row or 1 column. You

' can't enter a two-dimensional array. The formula must be

' entered into a single column or singe row. You cannot

' enter the formula in a two dimensional array. If the formula

' is entered into a two-dimensional range, or if DataRange is a

' two dimensional range, the function will return #REF errors.

' The size of the array is the greater of the number of cells

' into which it was entered and the number of cells in the input

' DataRange.

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

Dim N As Long

Dim N2 As Long

Dim Rng As Range

Dim MaxCells As Long

Dim Result() As Variant

Dim R As Long

Dim C As Long

If (DataRange.Rows.Count > 1) And _

    (DataRange.Columns.Count > 1) Then

    '''''''''''''''''''''''''''''''''''''''''''''''''

    ' If DataRange is a two-dimensional array, fill

    ' it with #REF errors. We work with only

    ' single dimensional ranges.

    '''''''''''''''''''''''''''''''''''''''''''''''''

    ReDim Result(1 To DataRange.Rows.Count, 1 To DataRange.Columns.Count)

    For R = 1 To UBound(Result, 1)

        For C = 1 To UBound(Result, 2)

            Result(R, C) = CVErr(xlErrRef)

        Next C

    Next R

    NoBlanks = Result

    Exit Function

End If

If (Application.Caller.Rows.Count > 1) And _

    (Application.Caller.Columns.Count > 1) Then

    '''''''''''''''''''''''''''''''''''''''''''''''''

    ' If Application.Caller is a two-dimensional array, fill

    ' it with #REF errors. We work with only

    ' single dimensional ranges.

    '''''''''''''''''''''''''''''''''''''''''''''''''

    ReDim Result(1 To Application.Caller.Rows.Count, 1 To Application.Caller.Columns.Count)

    For R = 1 To UBound(Result, 1)

        For C = 1 To UBound(Result, 2)

            Result(R, C) = CVErr(xlErrRef)

        Next C

    Next R

    NoBlanks = Result

    Exit Function

End If

'''''''''''''''''''''''''''''''''''''''''''''''''''''

' Get the greater of Application.Caller.Cells.Count

' and DataRange.Cells.Count. This is the size

' of the array we'll return. Sizing it to the

' maximum value prevents #N/A error from appearing

' in cells past the end of the array, because

' the array will always fill out the cells

' into which it was entered.

'''''''''''''''''''''''''''''''''''''''''''''''''''''

MaxCells = Application.WorksheetFunction.Max( _

    Application.Caller.Cells.Count, DataRange.Cells.Count)

''''''''''''''''''''''''''''''''''''''''''''

' Resize the array to the proper size.

''''''''''''''''''''''''''''''''''''''''''''

ReDim Result(1 To MaxCells, 1 To 1)

''''''''''''''''''''''''''''''''''''''''''''

' Loop through DataRange and place non-blank

' cells at the front of the array.

''''''''''''''''''''''''''''''''''''''''''''

For Each Rng In DataRange.Cells

    If Rng.Value <> vbNullString Then

        N = N + 1

        Result(N, 1) = Rng.Value

    End If

Next Rng

''''''''''''''''''''''''''''''''''''''''''''

' Fill the remaining array elements with

' vbNullStrings so they don't appear

' as 0 on the worksheet.

''''''''''''''''''''''''''''''''''''''''''''

For N2 = N + 1 To MaxCells

    Result(N2, 1) = vbNullString

Next N2

'''''''''''''''''''''''''''''''''''''''''''

' If the formula was entered into a single

' row across several columns, Transpose the

' result array.

'''''''''''''''''''''''''''''''''''''''''''

If Application.Caller.Rows.Count = 1 Then

    NoBlanks = Application.Transpose(Result)

Else

    NoBlanks = Result

End If

End Function
Summing Every Nth Value

You can easily sum (or average) every Nth cell in a column range. For example, suppose you want to sum every 3rd cell. 

Suppose your data is in A1:A20, and N = 3 is in D1. The following Array Formula will sum the values in A3, A6, A9, etc.

=SUM(IF(MOD(ROW($A$1:$A$20),$D$1)=0,$A$1:$A$20,0))

If you want to sum the values in A1, A4, A7, etc., use the following array formula:

=SUM(IF(MOD(ROW($A$1:$A$20)-1,$D$1)=0,$A$1:$A$20,0))

If your data ranges does not begin in row 1, the formulas are slightly more complicated. Suppose our data is in B3:B22, and N = 3 is in D1. To sum the values in rows 5, 8, 11, etc, use the following Array Formula : 

=SUM(IF(MOD(ROW($B$3:$B$22)-ROW($B$3)+1,$D$1)=0,$B$3:B$22,0))

If you want to sum the values in rows 3, 6, 9, etc, use the following Array Formula : 

=SUM(IF(MOD(ROW($B$3:$B$22)-ROW($B$3),$D$1)=0,$B$3:B$22,0))

Miscellaneous

Sheet Name
Suppose our active sheet is named "MySheet" in the file C:\Files\MyBook.Xls.

To return the full sheet name (including the file path) to a cell, use

=CELL("filename",A1)

Note that the argument to the =CELL function is the word "filename" in quotes, not your 
actual filename.

This will return "C:\Files\[MyBook.xls]MySheet"

To return the sheet name, without the path, use 

=MID(CELL("filename",A1),FIND("]",CELL("filename",A1))+1,
LEN(CELL("filename",A1))-FIND("]",CELL("filename",A1)))

This will return "MySheet"

File Name
Suppose our active sheet is named "MySheet" in the file C:\Files\MyBook.Xls.

To return the file name without the path, use 

=MID(CELL("filename",A1),FIND("[",CELL("filename",A1))+1,FIND("]",
CELL("filename",A1))-FIND("[",CELL("filename",A1))-1)

This will return "MyBook.xls"

To return the file name with the path, use either

=LEFT(CELL("filename",A1),FIND("]",CELL("filename",A1))) Or 

=SUBSTITUTE(SUBSTITUTE(LEFT(CELL("filename",A1),FIND("]",
CELL("filename",A1))),"[",""),"]","")

The first syntax will return "C:\Files\[MyBook.xls]"

The second syntax will return "C:\Files\MyBook.xls"

In all of the examples above, the A1 argument to the =CELL function forces Excel to get the sheet name from the sheet containing the formula. Without it, and Excel calculates the =CELL function when another sheet is active, the cell would contain the name of the active sheet, not the sheet actually containing the formula.

